% Funny thing, this. Must be placed within a separate file; pasting this inline
% causes errors.
\begin{gnuplot}[terminal=epslatex]
  set size 0.55,0.7
  set auto x
  set yrange [0:*]
  set ylabel "Ops/s (millions)"
  set key above horizontal autotitle columnheader

  # styling
  set decimal locale
  set format "%'g"
  set border 3 front
  set style data histogram
  set style fill solid border -1
  set tics scale 0.0
  set grid y
  set xtics offset 1

  # to align properly with LaTeX subfloat caption and not stretch the page
  set lmargin 1
  set rmargin 0

  # load data from csv file
  set datafile separator ","
  plot "data/func-wrap-invoke.dat" using 2:xtic(1) lc rgb "gray", \
  '' u 4 lc rgb "#eeeeec", \
  '' using ($0):($2+30):($2) with labels notitle, \
  '' using ($0+0.25):($4+30):($4) with labels notitle, \
  '' using ($0+0.45):($4+230):\
    (sprintf('\\footnotesize'."(-%'g".'\\%)',$5)) \
    with labels notitle rotate by 45
\end{gnuplot}
